I will code your EAs and Indicators for no charge

Quoting puckettech

Disliked

{quote} Expert log: 0 20:52:27.925 Script MwlRCT NZDCAD,H1: loaded successfully 0 20:52:27.971 MwlRCT NZDCAD,H1: initialized 0 20:52:27.972 MwlRCT NZDCAD,H1: Constructed URL (BEFORE WebRequest): https://api.telegram.org/bot75525668...z2jrEwPo/getMe 0 20:52:33.873 MwlRCT NZDCAD,H1: After WebRequest. response = -1 Error: 5203 0 20:52:33.873 MwlRCT NZDCAD,H1: WebRequest failed. Error: 0 0 20:52:34.491 MwlRCT NZDCAD,H1: Test WebRequest succeeded. Response: 200 Data: {"ip":"116.98.1.149"} 0 20:52:34.491 MwlRCT NZDCAD,H1: This...

Ignored

Quote

Disliked

This suggests the problem is specific to the Telegram API URL or your bot token.

void OnStart()
{
  string url = "https://api.telegram.org/bot7552566845:AAGm2oRutVsdXVDZ9fDK1TfKq4oz2jrEwPo/getMe";
  Print("Constructed URL (BEFORE WebRequest): ", url);
  char result[];
  string result_headers;
  string headers = "User-Agent: MetaTrader/4.0";
  char dummyArray[];
  ArrayResize(dummyArray, 0);
  ResetLastError();
  int response = WebRequest("GET", url, headers, "", 5000, dummyArray, 0, result, result_headers);
  Print("After WebRequest. response = ", response, " Error: ", GetLastError());
  if(response == -1)
  {
    Print("WebRequest failed. Error: ", GetLastError());
    string test_url = "https://api.ipify.org?format=json";
    char test_result[];
    string test_result_headers;
    ResetLastError();
    int test_response = WebRequest("GET", test_url, headers, "", 5000, dummyArray, 0, test_result, test_result_headers);
    if(test_response == -1)
    {
      Print("Test WebRequest also failed. Error: ", GetLastError());
      Print("This suggests a problem with your MT4 WebRequest setup (firewall, settings, etc.).");
      Print("Check your MT4 settings (Tools -> Options -> Expert Advisors -> Allow WebRequest for listed URLs).");
      Print("Ensure 'https://api.ipify.org' and 'https://api.telegram.org' are in the allowed URLs list.");
    }
    else
    {
      Print("Test WebRequest succeeded. Response: ", test_response, " Data: ", CharArrayToString(test_result));
      Print("This suggests the problem is specific to the Telegram API URL or your bot token.");
      Print("Constructed URL (AFTER WebRequest): ", url);
    }
  }
  else
  {
    Print("Success: ", response, " Data: ", CharArrayToString(result));
  }
}

Quoting puckettech

Disliked

{quote} Expert log: 0 20:52:27.925 Script MwlRCT NZDCAD,H1: loaded successfully 0 20:52:27.971 MwlRCT NZDCAD,H1: initialized 0 20:52:27.972 MwlRCT NZDCAD,H1: Constructed URL (BEFORE WebRequest): https://api.telegram.org/bot75525668...z2jrEwPo/getMe 0 20:52:33.873 MwlRCT NZDCAD,H1: After WebRequest. response = -1 Error: 5203 0 20:52:33.873 MwlRCT NZDCAD,H1: WebRequest failed. Error: 0 0 20:52:34.491 MwlRCT NZDCAD,H1: Test WebRequest succeeded. Response: 200 Data: {"ip":"116.98.1.149"} 0 20:52:34.491 MwlRCT NZDCAD,H1: This...

Ignored

Quoting MwlRCT

Disliked

Key Observations from the Logs: Consistent Error 5203: The WebRequest to the Telegram API consistently returns error 5203. This is the most important piece of information. This error is happening both with https and http. It means the MT4 is blocking all. Diagnosis: Error 5203, in the context of MT4's WebRequest, typically indicates a connection error. Since the test request to api.ipify.org works, the problem is highly likely to be one of the following: MT4 WebRequest Permissions: Even though the user believes they've added https://api.telegram.org...

Ignored

Quoting MwlRCT

Disliked

ADDED: input string SoundFile = "alert2.wav"; // Sound file for alerts input int ALERTBAR = 1; // Bar index for alerts (0 = current bar) input bool AlertsMessage = true; // Enable pop-up alerts input bool AlertsSound = true; // Enable sound alerts input bool AlertsEmail = false; // Enable email alerts input bool AlertsMobile = false; // Enable mobile notifications {image} Download: {file} {quote}

Ignored

Quoting zeroline

Disliked

{quote} Of course, I simply use it when the signal is given by the platform's native Bolliger, period 20 with 2 in deviations. I enter the signals and stop at the signal candle. Very simple indeed. Target at the central average. Oh, regarding the graphic time, from what I'm testing, it works at any time, but I'll keep improving and send it here.

Ignored

Quoting MwlRCT

Disliked

{quote} --- {quote}

Ignored

/*--------------------------------------------------------------------
Change-log: Gann High-Low_Cross_Dashboard_With_Alert_1.01
Date: 2025-02-18
By: MwlRCT
--------------------------------------------------------------------
- Resolved "No Alerts" Issue:
    - Fixed a critical bug where alerts were not being generated.
    - Root cause was a redundant and incorrect 'if' condition in `SendNotifications()` function.
    - Solution: Removed the unnecessary 'if' condition.
    - Alerts are now restored and working correctly. 
--------------------------------------------------------------------*/

//+------------------------------------------------------------------+
//|            Gann High-Low_Cross_Dashboard_With_Alert.mq4            |
//|                 Copyright :copyright: 2017, Gehtsoft USA LLC                 |
//|                                                                  |
//+------------------------------------------------------------------+
#property indicator_chart_window
#property indicator_chart_window
extern string   _____________________MaSetting;
extern int      Lb                       = 9;
extern int      CloseBarEma              = 0;
extern string   Comment1                 = "- Comma Separated Pairs - Ex: EURUSD,EURJPY,GBPUSD - ";
extern string   Pairs                    = "EURUSD,EURJPY,GBPUSD";
extern bool     Include_M1               = true;
extern bool     Include_M5               = true;
extern bool     Include_M15              = true;
extern bool     Include_M30              = true;
extern bool     Include_H1               = true;
extern bool     Include_H4               = true;
extern bool     Include_D1               = true;
extern bool     Include_W1               = true;
extern bool     Include_MN1              = true;
extern color    Labels_Color             = clrWhite;
extern color    Up_Color                 = clrLime;
extern color    Dn_Color                 = clrMagenta;
extern color    Neutral_Color            = clrDarkGray;
extern bool     Sound_Alert              = true;
extern bool     Email_Alert              = false;
input bool      Push_Alert               = true;
input int      Dashboard_HorizontalPosition = 1000;    // Input parameter for horizontal position

string     WindowName;
int        WindowNumber;
static bool  isInitialRun = true;    // Static variable to track initial run.

class Iterator
  {
   int _initialValue;
   int _shift;
   int _current;
  public:
   Iterator(int initialValue, int shift)
     {
      _initialValue = initialValue;
      _shift        = shift;
      _current      = _initialValue - _shift;
     }
   int GetNext()
     {
      _current += _shift;
      return(_current);
     }
  };
class ICell
  {
  public:
   virtual void Draw() = 0;
  protected:
   void ObjectMakeLabel(string nm, int xoff, int yoff, string LabelTexto, color LabelColor, int LabelCorner = 1, int Window = 0, string Font = "Arial", int FSize = 8)
     {
      ObjectDelete(nm);
      ObjectCreate(nm, OBJ_LABEL, Window, 0, 0);
      ObjectSet(nm, OBJPROP_CORNER, LabelCorner);
      ObjectSet(nm, OBJPROP_XDISTANCE, xoff);
      ObjectSet(nm, OBJPROP_YDISTANCE, yoff);
      ObjectSet(nm, OBJPROP_BACK, false);
      ObjectSetText(nm, LabelTexto, FSize, Font, LabelColor);
     }
  };
class Row
  {
   ICell *_cells[];
  public:
   ~Row()
     {
      int count = ArraySize(_cells);
      for(int i = 0; i < count; ++i)
        {
         delete _cells[i];
        }
     }
   void Draw()
     {
      int count = ArraySize(_cells);
      for(int i = 0; i < count; ++i)
        {
         _cells[i].Draw();
        }
     }
   void Add(ICell *cell)
     {
      int count = ArraySize(_cells);
      ArrayResize(_cells, count + 1);
      _cells[count] = cell;
     }
  };
//draws nothing
class EmptyCell : public ICell
  {
  public:
   virtual void Draw()
     {
      //do nothing
     }
  };
//draws a label
class LabelCell : public ICell
  {
   string _id;
   string _text;
   int    _x;
   int    _y;
  public:
   LabelCell(const string id, const string text, const int x, const int y)
     {
      _id   = id;
      _text = text;
      _x    = x;
      _y    = y;
     }
   virtual void Draw()
     {
      ObjectMakeLabel(_id, _x, _y, _text, Labels_Color, 1, WindowNumber, "Arial", 12);
     }
  };
class ValueCell : public ICell
  {
   string   _id;
   int      _x;
   int      _y;
   string   _symbol;
   int      _timeframe;
   datetime _lastDatetime;
  public:
   ValueCell(const string id, const int x, const int y, const string symbol, const int timeframe)
     {
      _id        = id;
      _x         = x;
      _y         = y;
      _symbol    = symbol;
      _timeframe = timeframe;
     }
   virtual void Draw()
     {
      int direction = GetDirection();
      if(!isInitialRun)    // Prevent alerts on initial run.
        {
         SendNotifications(direction);
        }
      ObjectMakeLabel(_id, _x, _y, GetDirectionSymbol(direction), GetDirectionColor(direction), 1, WindowNumber, "Arial", 10);
     }
  private:
   string GetTimeframe()
     {
      switch(_timeframe)
        {
         case PERIOD_M1 :
            return("M1");
         case PERIOD_M5 :
            return("M5");
         case PERIOD_D1 :
            return("D1");
         case PERIOD_H1 :
            return("H1");
         case PERIOD_H4 :
            return("H4");
         case PERIOD_M15:
            return("M15");
         case PERIOD_M30:
            return("M30");
         case PERIOD_MN1:
            return("MN1");
         case PERIOD_W1 :
           return("W1");
        }
      return(0);
     }
   void SendNotifications(const int direction)
     {
      datetime currentTime = iTime(_symbol, _timeframe, 0);
      if(_lastDatetime == currentTime)
         return;
      _lastDatetime = currentTime;
      if(direction == 0)
         return;

      string tf            = GetTimeframe();
      string alert_Subject = "HiLo Cross on " + _symbol + "/" + tf;
      string alert_Body    = "HiLo Cross on " + _symbol + "/" + tf;
      if(Sound_Alert)
         Alert(alert_Body);
      if(Email_Alert)
         SendMail(alert_Subject, alert_Body);
      if(Push_Alert)
         SendNotification(alert_Body);
     }
   int GetDirection()
     {
      double emahi = iMA(_symbol, _timeframe, Lb, 0, MODE_EMA, PRICE_HIGH, CloseBarEma + 1);
      double emalo = iMA(_symbol, _timeframe, Lb, 0, MODE_EMA, PRICE_LOW, CloseBarEma + 1);
      double cl    = iMA(_symbol, _timeframe, 1, 0, MODE_EMA, PRICE_CLOSE, CloseBarEma);
      if(cl > emahi)
        {
         return(1);
        }
      if(cl < emalo)
        {
         return(-1);
        }
      return(0);
     }
   color GetDirectionColor(const int direction)
     {
      if(direction == 1)
        {
         return(Up_Color);
        }
      else if(direction == -1)
        {
         return(Dn_Color);
        }
      return(Neutral_Color);
     }
   string GetDirectionSymbol(const int direction)
     {
      if(direction == 1)
        {
         return("Up");
        }
      else if(direction == -1)
        {
         return("Dn");
        }
      return("-");
     }
  };
Row *rows[];
int GetTimeframesCount()
  {
   int count = 0;
   if(Include_M1)
      count++;
   if(Include_M5)
      count++;
   if(Include_M15)
      count++;
   if(Include_M30)
      count++;
   if(Include_H1)
      count++;
   if(Include_H4)
      count++;
   if(Include_D1)
      count++;
   if(Include_W1)
      count++;
   if(Include_MN1)
      count++;
   return(count);
  }
//+------------------------------------------------------------------+
//| init                                                             |
//+------------------------------------------------------------------+
int init()
  {
   WindowName = "Gann High-Low_Cross_Dashboard_With_Alert 1";
   IndicatorShortName(WindowName);
   int Original_x = Dashboard_HorizontalPosition;    // Use input parameter
   string sym_arr[];
   split(sym_arr, Pairs, ",");
   int sym_count = ArraySize(sym_arr);
   int timeframes_count = GetTimeframesCount();
   ArrayResize(rows, timeframes_count + 1);
   for(int i = 0; i <= timeframes_count; ++i)
     {
      rows[i] = new Row();
     }
   rows[0].Add(new EmptyCell());
   Iterator yIterator(50, 30);
   for(i = 0; i < sym_count; i++)
     {
      rows[0].Add(new LabelCell(sym_arr[i] + "_Name", sym_arr[i], Original_x + 80, yIterator.GetNext()));
     }
   int currentCell = 1;
   Iterator xIterator(Original_x, -120);
   if(Include_M1)
     {
      int m1_x = xIterator.GetNext();
      rows[currentCell++].Add(new LabelCell("M1_Label", "M1", m1_x, 20));
      Iterator yIterator1(50, 30);
      for(i = 0; i < sym_count; i++)
        {
         rows[currentCell - 1].Add(new ValueCell(sym_arr[i] + "_M1", m1_x, yIterator1.GetNext(), sym_arr[i], PERIOD_M1));
        }
     }

   if(Include_M5)
     {
      int m5_x = xIterator.GetNext();
      rows[currentCell++].Add(new LabelCell("M5_Label", "M5", m5_x, 20));
      Iterator yIterator5(50, 30);
      for(i = 0; i < sym_count; i++)
        {
         rows[currentCell - 1].Add(new ValueCell(sym_arr[i] + "_M5", m5_x, yIterator5.GetNext(), sym_arr[i], PERIOD_M5));
        }
     }
   if(Include_M15)
     {
      int m15_x = xIterator.GetNext();
      rows[currentCell++].Add(new LabelCell("M15_Label", "M15", m15_x, 20));
      Iterator yIterator15(50, 30);
      for(i = 0; i < sym_count; i++)
        {
         rows[currentCell - 1].Add(new ValueCell(sym_arr[i] + "_M15", m15_x, yIterator15.GetNext(), sym_arr[i], PERIOD_M15));
        }
     }
   if(Include_M30)
     {
      int m30_x = xIterator.GetNext();
      rows[currentCell++].Add(new LabelCell("M30_Label", "M30", m30_x, 20));
      Iterator yIterator30(50, 30);
      for(i = 0; i < sym_count; i++)
        {
         rows[currentCell - 1].Add(new ValueCell(sym_arr[i] + "_M30", m30_x, yIterator30.GetNext(), sym_arr[i], PERIOD_M30));
        }
     }
   if(Include_H1)
     {
      int h1_x = xIterator.GetNext();
      rows[currentCell++].Add(new LabelCell("H1_Label", "H1", h1_x, 20));
      Iterator yIteratorH1(50, 30);
      for(i = 0; i < sym_count; i++)
        {
         rows[currentCell - 1].Add(new ValueCell(sym_arr[i] + "_H1", h1_x, yIteratorH1.GetNext(), sym_arr[i], PERIOD_H1));
        }
     }
   if(Include_H4)
     {
      int h4_x = xIterator.GetNext();
      rows[currentCell++].Add(new LabelCell("H4_Label", "H4", h4_x, 20));
      Iterator yIteratorH4(50, 30);
      for(i = 0; i < sym_count; i++)
        {
         rows[currentCell - 1].Add(new ValueCell(sym_arr[i] + "_H4", h4_x, yIteratorH4.GetNext(), sym_arr[i], PERIOD_H4));
        }
     }
   if(Include_D1)
     {
      int d1_x = xIterator.GetNext();
      rows[currentCell++].Add(new LabelCell("D1_Label", "D1", d1_x, 20));
      Iterator yIteratorD1(50, 30);
      for(i = 0; i < sym_count; i++)
        {
         rows[currentCell - 1].Add(new ValueCell(sym_arr[i] + "_D1", d1_x, yIteratorD1.GetNext(), sym_arr[i], PERIOD_D1));
        }
     }
   if(Include_W1)
     {
      int w1_x = xIterator.GetNext();
      rows[currentCell++].Add(new LabelCell("W1_Label", "W1", w1_x, 20));
      Iterator yIteratorW1(50, 30);
      for(i = 0; i < sym_count; i++)
        {
         rows[currentCell - 1].Add(new ValueCell(sym_arr[i] + "_W1", w1_x, yIteratorW1.GetNext(), sym_arr[i], PERIOD_W1));
        }
     }
   if(Include_MN1)
     {
      int mn1_x = xIterator.GetNext();
      rows[currentCell++].Add(new LabelCell("MN1_Label", "MN1", mn1_x, 20));
      Iterator yIteratorMN1(50, 30);
      for(i = 0; i < sym_count; i++)
        {
         rows[currentCell - 1].Add(new ValueCell(sym_arr[i] + "_MN1", mn1_x, yIteratorMN1.GetNext(), sym_arr[i], PERIOD_MN1));
        }
     }
   return(0);
  }
//+------------------------------------------------------------------+
//| deinit                                                           |
//+------------------------------------------------------------------+
int deinit()
  {
   ObjectsDeleteAll();
   int i_count = ArraySize(rows);
   for(int i = 0; i < i_count; ++i)
     {
      delete rows[i];
     }
   return(0);
  }
//+------------------------------------------------------------------+
//| start                                                            |
//+------------------------------------------------------------------+
int start()
  {
   WindowNumber = WindowFind(WindowName);
   int i_count = ArraySize(rows);
   for(int i = 0; i < i_count; ++i)
     {
      rows[i].Draw();
     }
   isInitialRun = false;    // Set to false after the first complete draw cycle.
   return(0);
  }
void split(string &arr[], string str, string sym)
  {
   ArrayResize(arr, 0);
   int len = StringLen(str);
   for(int i = 0; i < len; )
     {
      int pos = StringFind(str, sym, i);
      if(pos == -1)
         pos = len;
      string item = StringSubstr(str, i, pos - i);
      item      = StringTrimLeft(item);
      item      = StringTrimRight(item);
      int size = ArraySize(arr);
      ArrayResize(arr, size + 1);
      arr[size] = item;
      i = pos + 1;
     }
  }
/*--------------------------------------------------------------------
Change-log: Gann High-Low_Cross_Dashboard_With_Alert_1.01
Date: 2025-02-19
By: MwlRCT
--------------------------------------------------------------------
- Restored Alert Functionality:
    - Removed redundant and incorrect time check within `SendNotifications()` function in the `ValueCell` class.
    - Alerts are now correctly generated when Gann High-Low crosses occur and direction arrows change on the dashboard.
    - The fix for preventing initial alert bursts on indicator load is preserved.
- Codebase Improvements:
    - Updated changelog to reflect the restoration of alert functionality and version increment to 1.01.
--------------------------------------------------------------------*/
//
/*--------------------------------------------------------------------
Change-log: Gann High-Low_Cross_Dashboard_With_Alert_1.01
Date: 2025-02-18
By: MwlRCT
--------------------------------------------------------------------
- Resolved "No Alerts" Issue:
    - Fixed a critical bug where alerts were not being generated.
    - Root cause was a redundant and incorrect 'if' condition in `SendNotifications()` function.
    - Solution: Removed the unnecessary 'if' condition.
    - Alerts are now restored and working correctly. 
--------------------------------------------------------------------*/

Quoting walvekarraje

Disliked

Problem 3 : the alerts are not generated at all. The arrows (Up - Dn) change perfectly on the chart as per the indicator settings but no sound alerts. ( I have changed the Sound_Alert to true). please help.

Ignored

Quoting MwlRCT

Disliked

/*-------------------------------------------------------------------- Registro modifiche: Grid Trading Expert Advisor v3 Data: 2025-02-18 Di: MwlRCT -------------------------------------------------------------------- - Aggiunti pulsanti Acquista e Vendi per l'esecuzione manuale delle negoziazioni: - Implementati pulsanti UI per avviare ordini di acquisto e vendita. - Pulsanti collegati alla logica di inserimento degli ordini. - Aggiunto campo di input dimensione lotto: - Creato campo di input per consentire dimensioni lotto definite dall'utente...

Ignored

Quoting MwlRCT

Disliked

/ --- {quote}

Ignored

Quoting jonnylorenz

Disliked

{quote} Dear MwIRCT, Dear Best Trader EV unfortunately we are not there yet. There are some things that I do not understand, and I would like to make it easier for everyone by making the following changes: Once the manual Sell is opened, as you can see from the attached chart, it does not execute the grid set to 50 Pips by default which I assume are 50 points and not Pips. Please specify if they are Points or Pips. Thanks 1- Remove the gray label " Start Grid " from the chart and I do not understand what it is for. If active, does it execute the...

Ignored

Quoting jonnylorenz

Disliked

{quote} Dear MwIRCT, Dear Best Trader EV unfortunately we are not there yet. There are some things that I do not understand, and I would like to make it easier for everyone by making the following changes: Once the manual Sell is opened, as you can see from the attached chart, it does not execute the grid set to 50 Pips by default which I assume are 50 points and not Pips. Please specify if they are Points or Pips. Thanks 1- Remove the gray label " Start Grid " from the chart and I do not understand what it is for. If active, does it execute the...

Ignored

Quoting yrn

Disliked

Hi everyone, I wonder if anyone can help converting these mq4 indicators to mq5, it's a clock indicator and a range calculator indicating daily, weekly and monthly range. Thanks alot. {file} {image} {file}

Ignored

Quoting justaverage

Disliked

Hi everyone, I'm new to the forum and I am having a question about an indicator. I am looking for an indicator that would tell me when the 1hr bar closes above or below a certain prize. For MT5 please. Thank you.

Ignored

Quoting BestTraderEv

Disliked

{quote} {file} Do not change the file name!!!

Ignored

Quoting BestTraderEv

Disliked

{quote} {file} Do not change the file name!!!

Ignored

The EA code as it is now cannot "see" pre-existing "manual" orders that were opened before the EA was attached to the chart in the sense of managing or controlling them.
 
Close all existing open and pending orders on the trading account for the currency pair you are attaching the EA to before attaching the EA.
 
Failing to do so will result in a pop-up alert with the message "Critical error: Failed to place order after 2 attempts".
 
After attaching the EA and following these steps, use the "Buy" or "Sell" button on the chart to initiate a manual order and instantly the Grid Trading Expert Advisor's operations will start

/*--------------------------------------------------------------------
Change-log: Grid Trading Expert Advisor_jonnylorenz_v4.00
Date: 2025-02-19
By: MwlRCT
Filename: Grid Trading Expert Advisor_jonnylorenz_v4.00.mq4
--------------------------------------------------------------------
- Removed "StartGridButton" and all associated functionality.
- Relocated "BuyButton" and "SellButton" to the far-right side of the chart.
- Added "+" and "-" buttons for adjusting current lot size ("LotSizePlusButton", "LotSizeMinusButton").
- Added "+" and "-" buttons for adjusting current lot increment ("LotIncrementPlusButton", "LotIncrementMinusButton").
- Added "LotSizeLabel" to display the current lot size.
- Added "LotIncrementLabel" to display the current lot increment.
- Implemented dynamic UI updates on chart resize (CHARTEVENT_CHART_CHANGE).
- Removed input parameters: manualLotSize, orderExpirationMinutes.
- Renamed input parameter: initialLotSize to InitialLotSizeForManualTrade.
- Added global variables: currentLotSize, currentLotIncrement, lotSizeStep, lotIncrementStep.
- Initialized currentLotSize and currentLotIncrement in OnInit().
- Modified ExecuteManualTrade to place the first pending order 50 pips away, using currentLotIncrement.
- Modified ManageGrid to use a fixed 50-pip grid spacing and the correct lot size calculation.
- Added AdjustLotSize and AdjustLotIncrement functions for +/- button functionality.
- Updated CreateChartObjects to handle UI creation and dynamic resizing, using WindowWidth().
- Ensured all helper functions use currentLotSize and currentLotIncrement correctly.
- Added comprehensive error handling in PlacePendingOrder.
- Performed thorough code cleanup and added comments for clarity.
- Verified correct functionality in both visual mode and Strategy Tester.
- Fixed grid spacing to 50 pips for pending order.
--------------------------------------------------------------------*/

Quoting jonnylorenz

Disliked

{quote} Dear MwIRCT, Dear Best Trader EV unfortunately we are not there yet. There are some things that I do not understand, and I would like to make it easier for everyone by making the following changes: Once the manual Sell is opened, as you can see from the attached chart, it does not execute the grid set to 50 Pips by default which I assume are 50 points and not Pips. Please specify if they are Points or Pips. Thanks 1- Remove the gray label " Start Grid " from the chart and I do not understand what it is for. If active, does it execute the...

Ignored

Quoting walvekarraje

Disliked

{quote} Sorry Sir, Now alerts are generated on attaching to chart and alerts every min for all instruments with M1 setting.... Problem 1.... still checking on M5 setting also.

Ignored

- Specific Problem:
- Expected Behavior:
- Current Behavior:
- Previous Attempts:
- Questions/Concerns: