//+------------------------------------------------------------------+
//|                                                                  |
//| original NonLag moving average developed by igorad               |
//| this version made by mladen                                      | 
//+------------------------------------------------------------------+

#property indicator_chart_window
#property indicator_buffers 3
#property indicator_color1  DeepSkyBlue
#property indicator_color2  OrangeRed
#property indicator_color3  OrangeRed
#property indicator_width1  2
#property indicator_width2  2
#property indicator_width3  2

//
//
//
//
//

extern string TimeFrame       = "Current time frame";
extern int    Length          = 14;
extern int    Price           = PRICE_CLOSE;
extern bool   MultiColor      = true;
extern bool   Interpolate     = true;
extern bool   alertsOn        = true;
extern bool   alertsOnCurrent = true;
extern bool   alertsMessage   = true;
extern bool   alertsSound     = false;
extern bool   alertsEmail     = false;

//
//
//
//
//

double NonLagMaBuffer[];
double NonLagMaBufferUa[];
double NonLagMaBufferUb[];
double trend[];
double alphas[];

//
//
//
//
//

string indicatorFileName;
bool   returnBars;
bool   calculateValue;
int    timeFrame;

//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

int init()
{
   IndicatorBuffers(4);
   SetIndexBuffer(0,NonLagMaBuffer);
   SetIndexBuffer(1,NonLagMaBufferUa);
   SetIndexBuffer(2,NonLagMaBufferUb);
   SetIndexBuffer(3,trend);
   
      //
      //
      //
      //
      //
      
         indicatorFileName = WindowExpertName();
         calculateValue    = TimeFrame=="calculateValue"; if (calculateValue) { return(0); }
         returnBars        = TimeFrame=="returnBars";     if (returnBars)     { return(0); }
         timeFrame         = stringToTimeFrame(TimeFrame);
      
      //
      //
      //
      //
      //
               
   IndicatorShortName(timeFrameToString(timeFrame)+" non lag MA ("+Length+")");
   return(0);  
}

//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

int start()
{
   int counted_bars=IndicatorCounted();
   int i,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
         limit = MathMin(Bars-counted_bars,Bars-1);
         if (returnBars) { NonLagMaBuffer[0] = MathMin(limit+1,Bars-1); return(0); }

   //
   //
   //
   //
   //
   
   if (calculateValue || timeFrame == Period())
   {
      if (MultiColor && !calculateValue && trend[limit]==-1) CleanPoint(limit,NonLagMaBufferUa,NonLagMaBufferUb);
      
      //
      //
      //
      //
      //
      
      for (i=limit; i>=0; i--)
      {
          NonLagMaBuffer[i]   = iNoLagMa(iMA(NULL,0,1,0,MODE_SMA,Price,i),Length,alphas,0,i);
          NonLagMaBufferUa[i] = EMPTY_VALUE;
          NonLagMaBufferUb[i] = EMPTY_VALUE;
          trend[i]            = trend[i+1];
 
            if (NonLagMaBuffer[i]>NonLagMaBuffer[i+1]) trend[i]= 1;
            if (NonLagMaBuffer[i]<NonLagMaBuffer[i+1]) trend[i]=-1;
            if (MultiColor && !calculateValue && trend[i]==-1) PlotPoint(i,NonLagMaBufferUa,NonLagMaBufferUb,NonLagMaBuffer);
      }            
      manageAlerts();
   	return(0);	
   }	  

   //
   //
   //
   //
   //
   //
   
   limit = MathMax(limit,MathMin(Bars-1,iCustom(NULL,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));
   if (MultiColor && trend[limit]==-1) CleanPoint(limit,NonLagMaBufferUa,NonLagMaBufferUb);
   for (i=limit;i>=0;i--)
   {
      int y = iBarShift(NULL,timeFrame,Time[i]);
         NonLagMaBuffer[i]   = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Length,Price,false,0,y);
         NonLagMaBufferUa[i] = EMPTY_VALUE;
         NonLagMaBufferUb[i] = EMPTY_VALUE;
         trend[i]            = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Length,Price,false,3,y);

         //
         //
         //
         //
         //
      
         if (timeFrame <= Period() || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;
         if (!Interpolate) continue;

         //
         //
         //
         //
         //

            datetime time = iTime(NULL,timeFrame,y);
               for(int n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
               for(int k = 1; k < n; k++)
                  NonLagMaBuffer[i+k] = NonLagMaBuffer[i] + (NonLagMaBuffer[i+n] - NonLagMaBuffer[i])*k/n;
   }
   if (MultiColor) for (i=limit;i>=0;i--) if (trend[i]==-1) PlotPoint(i,NonLagMaBufferUa,NonLagMaBufferUb,NonLagMaBuffer);
   manageAlerts();
   
   //
   //
   //
   //
   //
      
   return(0);
}


//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

double values[][3];
double prices[][1];

#define Pi       3.14159265358979323846264338327950288
#define _length  0
#define _len     1
#define _weight  2

//
//
//
//
//

double iNoLagMa(double price, int length, double &alphasArray[], int forValue, int i)
{
   if (ArrayRange(prices,0) != Bars) ArrayResize(prices,Bars);
            int r = Bars-i-1;  prices[r][forValue]=price;
   if (length<3 || r<3) return(prices[r][forValue]);
   
   //
   //
   //
   //
   //
   
   if (ArrayRange(values,0)<(forValue+1) || values[forValue][_length] != length)
   {
      double Cycle = 4.0;
      double Coeff = 3.0*Pi;
      int    Phase = length-1;
      
      if (ArrayRange(values,0)<forValue+1) ArrayResize(values,forValue+1);

         values[forValue][_length] = length;
         values[forValue][_len]    = length*4 + Phase;  
         values[forValue][_weight] = 0;  
         ArrayResize(alphasArray,values[forValue][_len]);

         for (int k=0; k<values[forValue][_len]-1; k++)
         {
            if (k<=Phase-1) 
                 double t = 1.0 * k/(Phase-1);
            else        t = 1.0 + (k-Phase+1)*(2.0*Cycle-1.0)/(Cycle*length-1.0); 
            double beta = MathCos(Pi*t);
            double g = 1.0/(Coeff*t+1); if (t <= 0.5 ) g = 1;
      
            alphasArray[k]             = g * beta;
            values[forValue][_weight] += alphasArray[k];
         }
   }
   
   //
   //
   //
   //
   //
   
   if (values[forValue][_weight]>0)
   {
      int    len = values[forValue][_len];
      double sum = 0;
           for (k=0; k < len-1; k++) sum += alphasArray[k]*prices[r-k][forValue];      
           return( sum / values[forValue][_weight]);
   }
   else return(0);           
}



//+-------------------------------------------------------------------
//|                                                                  
//+-------------------------------------------------------------------
//
//
//
//
//

void manageAlerts()
{
   if (!calculateValue && alertsOn)
   {
      if (alertsOnCurrent)
           int whichBar = 0;
      else     whichBar = 1; whichBar = iBarShift(NULL,0,iTime(NULL,timeFrame,whichBar));
      if (trend[whichBar] != trend[whichBar+1])
      {
         if (trend[whichBar] ==  1) doAlert(whichBar,"up");
         if (trend[whichBar] == -1) doAlert(whichBar,"down");
      }
   }
}

//
//
//
//
//

void doAlert(int forBar, string doWhat)
{
   static string   previousAlert="nothing";
   static datetime previousTime;
   string message;
   
   if (previousAlert != doWhat || previousTime != Time[forBar]) {
       previousAlert  = doWhat;
       previousTime   = Time[forBar];

       //
       //
       //
       //
       //

       message =  StringConcatenate(Symbol()," ",timeFrameToString(timeFrame)," at ",TimeToStr(TimeLocal(),TIME_SECONDS)," NonLagMA changed direction to ",doWhat);
          if (alertsMessage) Alert(message);
          if (alertsEmail)   SendMail(StringConcatenate(Symbol(),"NonLagMA "),message);
          if (alertsSound)   PlaySound("alert2.wav");
   }
}

//+-------------------------------------------------------------------
//|                                                                  
//+-------------------------------------------------------------------
//
//
//
//
//

void CleanPoint(int i,double& first[],double& second[])
{
   if ((second[i]  != EMPTY_VALUE) && (second[i+1] != EMPTY_VALUE))
        second[i+1] = EMPTY_VALUE;
   else
      if ((first[i] != EMPTY_VALUE) && (first[i+1] != EMPTY_VALUE) && (first[i+2] == EMPTY_VALUE))
          first[i+1] = EMPTY_VALUE;
}

//
//
//
//
//

void PlotPoint(int i,double& first[],double& second[],double& from[])
{
   if (first[i+1] == EMPTY_VALUE)
      {
         if (first[i+2] == EMPTY_VALUE) {
                first[i]   = from[i];
                first[i+1] = from[i+1];
                second[i]  = EMPTY_VALUE;
            }
         else {
                second[i]   =  from[i];
                second[i+1] =  from[i+1];
                first[i]    = EMPTY_VALUE;
            }
      }
   else
      {
         first[i]  = from[i];
         second[i] = EMPTY_VALUE;
      }
}

//+-------------------------------------------------------------------
//|                                                                  
//+-------------------------------------------------------------------
//
//
//
//
//

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = stringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string stringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int char = StringGetChar(s, length);
         if((char > 96 && char < 123) || (char > 223 && char < 256))
                     s = StringSetChar(s, length, char - 32);
         else if(char > -33 && char < 0)
                     s = StringSetChar(s, length, char + 224);
   }
   return(s);
}