//+------------------------------------------------------------------+
//|                                  Kaufman Adaptive Moving Average |
//|                                            Kaufman AMA basic.mq4 |
//|                                                           mladen |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      ""

#property indicator_separate_window
#property indicator_buffers 3
#property indicator_color1  clrLimeGreen
#property indicator_color2  clrOrange
#property indicator_width1  2
#property indicator_width2  2
#property indicator_minimum 0
#property indicator_maximum 1
#property strict

//
//
//
//
//

extern int                AMAPeriod        = 10;          // AMA period
extern ENUM_APPLIED_PRICE AMAPrice         = PRICE_CLOSE; // Price
extern int                Nfast            = 2;           // Fast end
extern int                Nslow            = 30;          // Slow end
extern double             GCoeff           = 2;           // Power
extern double             PriceFilter      = 15;          // Price filter period (<=0, no filter)
extern double             PriceFilterPhase = 0;           // Price filter phase

//
//
//
//
//

double kAMAbuffer[];
double kAMAbufferda[];
double kAMAbufferdb[];
double wAMAbuffer[];
double diff[];
double slope[];

double fastend;
double slowend;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   IndicatorBuffers(6);
   SetIndexBuffer(0,kAMAbufferda); SetIndexStyle(0,DRAW_HISTOGRAM);
   SetIndexBuffer(1,kAMAbufferdb); SetIndexStyle(1,DRAW_HISTOGRAM);
   SetIndexBuffer(2,kAMAbuffer);
   SetIndexBuffer(3,wAMAbuffer);
   SetIndexBuffer(4,diff);
   SetIndexBuffer(5,slope);
   
   //
   //
   //
   //
   //
   
      fastend   = (2.0 /(Nfast + 1));
      slowend   = (2.0 /(Nslow + 1));
   
   //
   //
   //
   //
   //
   
   IndicatorShortName("Kaufman AMA ("+(string)AMAPeriod+")");
   return(0);
}
int deinit()
{
   return(0);
}


//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int start()
{
   int counted_bars=IndicatorCounted();
      if(counted_bars<0) return(-1);
      if(counted_bars>0) counted_bars--;
         int limit = MathMin(Bars-counted_bars,Bars-1);

   //
   //
   //
   //
   //
   
   for(int i=limit; i>=0; i--)
   {
      kAMAbuffer[i]   = iKama(kAMAbuffer,diff,AMAPeriod,AMAPrice,GCoeff,i);
      kAMAbufferda[i] = EMPTY_VALUE;
      kAMAbufferdb[i] = EMPTY_VALUE;
      if (i<Bars-1)
      {
         slope[i] = slope[i+1];
            if (kAMAbuffer[i]>kAMAbuffer[i+1]) slope[i] =  1;
            if (kAMAbuffer[i]<kAMAbuffer[i+1]) slope[i] = -1;
      }            
      if (slope[i]== 1) kAMAbufferda[i] = 1;
      if (slope[i]==-1) kAMAbufferdb[i] = 1;
   }      
   return(0);
}
  
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//

double price[];
double iKama(double& ama_buffer[],double& diff_buffer[],int period,int priceType,double gCoeff,int i)
{
   double efratio  = 1.00;
   double AMA      = 0.00;
   if (ArraySize(price)!=Bars) ArrayResize(price,Bars); int r = Bars-i-1;
      price[r]    = iSmooth(iMA(NULL,0,1,0,MODE_SMA,priceType,i),PriceFilter,PriceFilterPhase,i);


   if (i>= Bars-period) return(price[r]);
   
   //
   //
   //
   //
   //
   
   double smooth;
   double signal;
   double noise=0;
          signal         = MathAbs(price[r]-price[r-period]);
          diff_buffer[i] = MathAbs(price[r]-price[r-1]);
          for (int k=0;k<period;k++)
                  noise += diff_buffer[i+k];

          //
          //
          //
          //
          //

          if (noise != 0) efratio = signal/noise;
                          smooth  = MathPow(efratio*(fastend-slowend)+slowend,gCoeff);
                          AMA     = ama_buffer[i+1] + smooth*(price[r]-ama_buffer[i+1]);
   //
   //
   //
   //
   //

   return(AMA);          
}

//------------------------------------------------------------------
//
//------------------------------------------------------------------
//
//
//
//
//

double wrk[][10];
#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iSmooth(double tprice, double length, double phase, int i, int s=0)
{
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars); 
   
   int r = Bars-i-1; s *= 10;
      if (r==0) { int k; for(k=0; k<7; k++) wrk[0][k+s]=tprice; for(; k<10; k++) wrk[0][k+s]=0; return(tprice); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = tprice - wrk[r-1][bsmax+s];
      double del2   = tprice - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            double dVolty = 0;
            if (wrk[r][avolty+s] > 0) dVolty = wrk[r][volty+s]/wrk[r][avolty+s];
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = tprice; else wrk[r][bsmax+s] = tprice - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = tprice; else wrk[r][bsmin+s] = tprice - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = tprice + alpha*(wrk[r-1][0+s]-tprice);
         wrk[r][1+s] = (tprice - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}