//+------------------------------------------------------------------+
//|                                                  TickMACD_v1.mq4 |
//|                             Copyright © 2007-08, TrendLaboratory |
//|                          Many Thanks to Rosh for Ticks indicator |
//|            http://finance.groups.yahoo.com/group/TrendLaboratory |
//|                                   E-mail: igorad2003@yahoo.co.uk |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2007-08, TrendLaboratory"
#property link      "http://finance.groups.yahoo.com/group/TrendLaboratory"


#property indicator_separate_window
#property indicator_buffers 2
#property indicator_color1 DodgerBlue
#property indicator_color2 Tomato
#property indicator_width1 2
#property indicator_width2 1
#property indicator_level1 0

//---- buffers
extern int     FastMA      =    12; //Fast MA Length(Period)
extern int     SlowMA      =    26; //Slow MA Length(Period)
extern int     SignalMA    =     9; //Slow MA Length(Period)
extern int     MA_Mode     =     1; //MA Mode: 0-SMA,1-EMA
extern int     UseDelimiter=     1; //Delimiter Mode: 0-off,1-on
extern color   DelimColor  =  Gray; //Color of Bars Delimiter 
extern int     MaxTicks    =   200; //Max Number of ticks   

double MACD[];
double Signal[];
double Fast[];
double Slow[];
double Ticks[];

int      tickCounter=0;
datetime pTime;
string   short_name, setup;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
{
//---- indicators
   IndicatorBuffers(5);
   SetIndexStyle(0,DRAW_HISTOGRAM);
   SetIndexBuffer(0, MACD);
   SetIndexStyle(1,DRAW_LINE);
   SetIndexBuffer(1, Signal);
   SetIndexBuffer(2, Fast);
   SetIndexBuffer(3, Slow);
   SetIndexBuffer(4, Ticks);
   
   IndicatorDigits(MarketInfo(Symbol(),MODE_DIGITS)+2);
   short_name="TicksMACD("+FastMA+","+SlowMA+","+SignalMA+","+MA_Mode+")";
   IndicatorShortName(short_name);
   SetIndexLabel(0,"MACD");
   SetIndexLabel(1,"Signal");
   
   SetIndexEmptyValue(0,0.0);
   SetIndexEmptyValue(1,0.0);
   
   setup = short_name+": ";
   pTime = Time[0];
//----
   return(0);
}
//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
{
//----
   ObjDel(setup);
//----
   return(0);
}
//---- 
void SetDelimeter()
{

   string delimeterName = setup + TimeToStr(Time[0]);
   
   int handle=WindowFind(short_name);
   if(!ObjectCreate(delimeterName,OBJ_VLINE,handle,Time[0],0))
   {
   Print("Error delimiter:",GetLastError());
   }
   else 
   {
   ObjectSet(delimeterName,OBJPROP_COLOR,DelimColor);
   ObjectSet(delimeterName,OBJPROP_STYLE,STYLE_DOT);
   }
}
//---- 
void ShiftArray()
{
   for(int cnt=tickCounter-1; cnt > 0; cnt--)
   {
   Ticks[cnt] = Ticks[cnt-1];
   Fast [cnt] = Fast[cnt-1];
   Slow [cnt] = Slow[cnt-1];
   MACD [cnt] = MACD[cnt-1];
   Signal[cnt] = Signal[cnt-1];
   }
   
   if (UseDelimiter!=0)
   {
      for (int j=0;j<ObjectsTotal();j++)
      {
      int NumStr = StringFind(ObjectName(j),setup,0);
      
         if (NumStr == 0)
         {
         datetime Time1=ObjectGet(ObjectName(j),OBJPROP_TIME1);
         int BarTime1=iBarShift(NULL,0,Time1);
         Time1 = Time[BarTime1+1];
         ObjectSet(ObjectName(j),OBJPROP_TIME1,Time1); 
            if( BarTime1+1 > MaxTicks )
            {
               if (!ObjectDelete(ObjectName(j)))
               {
               int _GetLastError = GetLastError();
               Print("ObjectDelete: ",ObjectName(j)," Error #", _GetLastError );
               }
            }
         }       
      }
   }      
}
//----
bool isNewBar()
{
   bool res=false;
   if (Time[0]!=pTime)
   {
   res=true;
   pTime=Time[0];
   }   
   return(res);
}
//----

bool ObjDel(string name)
{
   int _GetLastError = 0;
     
   while(ObjFind(name,0,0) > 0)
   {
      int obtotal = ObjectsTotal();
      for (int i = 0; i < obtotal;i++)
      {
         if (StringFind(ObjectName(i),name,0) >= 0)
         {
            if (!ObjectDelete(ObjectName(i)))
            {
            _GetLastError = GetLastError();
            Print( "ObjectDelete( \"",ObjectName(i),"\" ) - Error #", _GetLastError );
            }
         }
      }
   }      
   if(_GetLastError > 0) return(false);
   else
   return (true);
}
//-----
int ObjFind(string name,int start, int num)
{
   int cnt = 0;
   
   for (int i = 0; i < ObjectsTotal();i++)
      if (StringFind(ObjectName(i),name,start) == num) cnt+=1;
   
   return(cnt);
}         

//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
{
   if(tickCounter == 0)
   {
      for(int i=Bars-1;i>=0;i--)
      {
      MACD[i]=0.0;
      Signal[i]=0.0;
      }
   }
   
   tickCounter++;
   
   if(tickCounter >= MaxTicks) 
   {
   tickCounter = MaxTicks; 
   MACD[tickCounter]=0.0;
   Signal[tickCounter]=0.0;
   }
   
   if (isNewBar()) {if(UseDelimiter==1) SetDelimeter();}
   else
   ShiftArray();
   
   Ticks[0]=Bid;   
   
   if(MA_Mode == 0 || (MA_Mode == 1 && tickCounter<=SlowMA+SignalMA))
   {
      if(tickCounter>=SlowMA)
      { 
      Fast[0] = TickSMA(Ticks,FastMA);
      Slow[0] = TickSMA(Ticks,SlowMA);          
      MACD[0] = Fast[0] - Slow[0];
      }
   
      if(tickCounter>=SlowMA+SignalMA) Signal[0] = TickSMA(MACD,SignalMA);
   }   
   else
   if(MA_Mode == 1 && tickCounter > SlowMA+SignalMA)
   {
      Fast[0] = TickEMA(Ticks,Fast,FastMA);
      Slow[0] = TickEMA(Ticks,Slow,SlowMA);
      MACD[0] = Fast[0] - Slow[0];
      Signal[0] = TickEMA(MACD,Signal,SignalMA);
   }
   
//----
   return(0);
}
//+------------------------------------------------------------------+

double TickSMA(double array[],int per)
{
   double Sum = 0;
   for(int i = 0;i < per;i++) Sum += array[i];
   return(Sum/per);
}                

double TickEMA(double array1[],double array2[],int per)
{
   return(array2[1] + 2.0/(1+per)*(array1[0] - array2[1]));
}