//+------------------------------------------------------------------+
//|                                                       #dtosc.mq4 |
//|  29 Julie 2012                                          mladen   |
//+------------------------------------------------------------------+
#property copyright "mladen"
#property link      "mladenfx@gmail.com"


#property indicator_separate_window
#property indicator_buffers 5
#property indicator_minimum -5
#property indicator_maximum 105
#property indicator_color1  clrAqua  
#property indicator_color2  clrWhite//DimGray
#property indicator_color3  clrMagenta
#property indicator_color4  clrAqua
#property indicator_color5  clrRed
#property indicator_width4  2
#property indicator_width5  2
#property indicator_style1  STYLE_DASH
#property indicator_style2  STYLE_DASH
#property indicator_style3  STYLE_DASH

//
//
//
//
//

extern string TimeFrame             = "Current time frame";
extern int    PeriodRSI             = 5;//8
extern int    PeriodStoch           = 8;//14
extern int    PeriodSK              = 5;
extern int    PeriodSD              = 4;
extern int    MAMode                = 3;
extern double SmoothPeriod          = 5;//?????
extern int    SmoothPhase           = 0;
extern bool   SmoothDouble          = true;
extern int    MinMaxPeriod          =  50;
extern double LevelUp               =  95;
extern double LevelDown             =   5;

extern bool   ShowLinesOn100_0          = false;
extern bool   divergenceVisible         = true;
extern bool   divergenceOnValuesVisible = true;
extern bool   divergenceOnChartVisible  = true;
extern color  divergenceBullishColor    = clrAqua;// Green
extern color  divergenceBearishColor    = clrYellow;
extern string divergenceUniqueID        = "dtosc divergence1";
extern bool   Interpolate               = true;

extern bool   ShowLines             = true;//**********
extern bool   ShowLinesUp           = true;
extern bool   ShowLinesDown         = true;
extern bool   UseSignalLineFor100_0 = false;//***********

extern string LinesIdentifier       = "dtosc Lines";
extern color  LinesUpColor          = clrAqua;//**********
extern color  LinesDnColor          = clrMagenta;// ????
extern bool   alertsOn              = false;//*************
extern bool   alertsOnCurrent       = true;
extern bool   alertsMessage         = false;//*************
extern bool   alertsSound           = true;//false;
extern bool   alertsEmail           = false;
   
//
//
//
//
//

double SK[];
double SD[];
double StoRSI[];
double RSI[];
double trend[];
double levelUp[];
double levelMi[];
double levelDn[];

string IndicatorFileName;
int    timeFrame;
bool   returnBars;
bool   calculateValue;
string shortName;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//
//
//
//

int init()
{
   IndicatorBuffers(8);
      SetIndexBuffer(0,levelUp);
      SetIndexBuffer(1,levelMi);
      SetIndexBuffer(2,levelDn);
      SetIndexBuffer(3,SK);
      SetIndexBuffer(4,SD);
      SetIndexBuffer(5,StoRSI);
      SetIndexBuffer(6,RSI);
      SetIndexBuffer(7,trend);

   //
   //
   //
   //
   //
   
      IndicatorFileName = WindowExpertName();
      returnBars        = (TimeFrame == "returnBars"); if (returnBars)     return(0);
      calculateValue    = (TimeFrame=="calculateValue");
      if (calculateValue)
      {
         int s = StringFind(divergenceUniqueID,":",0);
               shortName = divergenceUniqueID;
               divergenceUniqueID = StringSubstr(divergenceUniqueID,0,s);
               return(0);
      }            
      timeFrame = stringToTimeFrame(TimeFrame);   

   //
   //
   //
   //
   //
   
   shortName = divergenceUniqueID+": "+timeFrameToString(timeFrame)+" DTOSC ("+PeriodRSI+","+PeriodStoch+","+PeriodSK+","+PeriodSD+")";
   IndicatorShortName(shortName);
   return(0);
}

//
//
//
//
//

int deinit()
{
   if (!calculateValue && ShowLines) deleteLines();
   int lookForLength = StringLen(divergenceUniqueID);
   
   for (int i=ObjectsTotal()-1; i>=0; i--) 
   {
      string name = ObjectName(i);  if (StringSubstr(name,0,lookForLength) == divergenceUniqueID) ObjectDelete(name);
   }
   return(0);
}


//+-------------------------------------------------------------------------------------------------------------------+
//|                                                                                                                   |
//+-------------------------------------------------------------------------------------------------------------------+
//
//
//
//
//

int start()
{
   int i,limit;
   int counted_bars = IndicatorCounted();

   if(counted_bars < 0) return(-1);
   if(counted_bars > 0) counted_bars--;
             limit=MathMin(Bars-counted_bars,Bars-1);
             if (returnBars) { levelUp[0] = limit; return(0); }

   //
   //
   //
   //
   //

   if (calculateValue || timeFrame == Period())
   {
      for(i=limit; i>=0; i--)
      {
         RSI[i] = iRSI(NULL,0,PeriodRSI,PRICE_CLOSE,i);
         double LLV = RSI[ArrayMinimum(RSI,PeriodStoch,i)];
         double HHV = RSI[ArrayMaximum(RSI,PeriodStoch,i)];
         if ((HHV-LLV)!=0)
               StoRSI[i] = iDSmooth(100.0*((RSI[i] - LLV)/(HHV - LLV)),SmoothPeriod,SmoothPhase,i);
         else  StoRSI[i] = iDSmooth(0,SmoothPeriod,SmoothPhase,i);
      }   
      for(i=limit; i>=0; i--) SK[i]=iMAOnArray(StoRSI,0,PeriodSK,0,MAMode,i);
      for(i=limit; i>=0; i--)
      {
         double hi = SK[ArrayMaximum(SK,MinMaxPeriod,i)];
         double lo = SK[ArrayMinimum(SK,MinMaxPeriod,i)];
         double rn = hi-lo;
               levelUp[i] = lo+rn*LevelUp  /100.0;
               levelDn[i] = lo+rn*LevelDown/100.0;
               levelMi[i] = (levelUp[i]+levelDn[i])/2.0;
         SD[i]=iMAOnArray(SK,0,PeriodSD,0,MAMode,i);
         trend[i] = trend[i+1];
            if (!ShowLinesOn100_0)
            {      
               if (SK[i]>SD[i]) trend[i] =  1;
               if (SK[i]<SD[i]) trend[i] = -1;
            }
            else
            {
               trend[i] = 0;
               if (UseSignalLineFor100_0)
               {
                  if (NormalizeDouble(SD[i],Digits) == 100) trend[i] = -1;
                  if (NormalizeDouble(SD[i],Digits) ==   0) trend[i] =  1;
               }
               else
               {
                  if (NormalizeDouble(SK[i],Digits) == 100) trend[i] = -1;
                  if (NormalizeDouble(SK[i],Digits) ==   0) trend[i] =  1;
               }
            }
         if (!calculateValue) manageLine(i);
         if (divergenceVisible)
         {
           CatchBullishDivergence(SK,i);
           CatchBearishDivergence(SK,i);
         } 
      }         
      manageAlerts();
      return(0);      
   }
   
   //
   //
   //
   //
   //
   
   limit = MathMax(limit,MathMin(Bars-1,iCustom(NULL,timeFrame,IndicatorFileName,"returnBars",0,0)*timeFrame/Period()));
   for(i=limit; i>=0; i--)
   {
      int y = iBarShift(NULL,timeFrame,Time[i]);
         levelUp[i] = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",PeriodRSI,PeriodStoch,PeriodSK,PeriodSD,MAMode,SmoothPeriod,SmoothPhase,SmoothDouble,MinMaxPeriod,LevelUp,LevelDown,ShowLinesOn100_0,divergenceVisible,divergenceOnValuesVisible,divergenceOnChartVisible,divergenceBullishColor,divergenceBearishColor,shortName,Interpolate,0,y);
         levelMi[i] = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",PeriodRSI,PeriodStoch,PeriodSK,PeriodSD,MAMode,SmoothPeriod,SmoothPhase,SmoothDouble,MinMaxPeriod,LevelUp,LevelDown,ShowLinesOn100_0,divergenceVisible,divergenceOnValuesVisible,divergenceOnChartVisible,divergenceBullishColor,divergenceBearishColor,shortName,Interpolate,1,y);
         levelDn[i] = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",PeriodRSI,PeriodStoch,PeriodSK,PeriodSD,MAMode,SmoothPeriod,SmoothPhase,SmoothDouble,MinMaxPeriod,LevelUp,LevelDown,ShowLinesOn100_0,divergenceVisible,divergenceOnValuesVisible,divergenceOnChartVisible,divergenceBullishColor,divergenceBearishColor,shortName,Interpolate,2,y);
         SK[i]      = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",PeriodRSI,PeriodStoch,PeriodSK,PeriodSD,MAMode,SmoothPeriod,SmoothPhase,SmoothDouble,MinMaxPeriod,LevelUp,LevelDown,ShowLinesOn100_0,divergenceVisible,divergenceOnValuesVisible,divergenceOnChartVisible,divergenceBullishColor,divergenceBearishColor,shortName,Interpolate,3,y);
         SD[i]      = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",PeriodRSI,PeriodStoch,PeriodSK,PeriodSD,MAMode,SmoothPeriod,SmoothPhase,SmoothDouble,MinMaxPeriod,LevelUp,LevelDown,ShowLinesOn100_0,divergenceVisible,divergenceOnValuesVisible,divergenceOnChartVisible,divergenceBullishColor,divergenceBearishColor,shortName,Interpolate,4,y);
         trend[i]   = iCustom(NULL,timeFrame,IndicatorFileName,"calculateValue",PeriodRSI,PeriodStoch,PeriodSK,PeriodSD,MAMode,SmoothPeriod,SmoothPhase,SmoothDouble,MinMaxPeriod,LevelUp,LevelDown,ShowLinesOn100_0,divergenceVisible,divergenceOnValuesVisible,divergenceOnChartVisible,divergenceBullishColor,divergenceBearishColor,shortName,Interpolate,7,y);
         manageLine(i);
         
         //
         //
         //
         //
         //
      
         if (timeFrame <= Period() || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;
         if (!Interpolate) continue;

         //
         //
         //
         //
         //

         datetime time = iTime(NULL,timeFrame,y);
            for(int n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;	
            for(int k = 1; k < n; k++)
            {
               SK[i+k] = SK[i] +(SK[i+n]-SK[i])*k/n;
               SD[i+k] = SD[i] +(SD[i+n]-SD[i])*k/n;
               levelUp[i+k] = levelUp[i] + (levelUp[i+n]-levelUp[i])*k/n;
               levelMi[i+k] = levelMi[i] + (levelMi[i+n]-levelMi[i])*k/n;
               levelDn[i+k] = levelDn[i] + (levelDn[i+n]-levelDn[i])*k/n;
            }               
   }               

   //
   //
   //
   //
   //
             
   manageAlerts();
   return(0);
}


//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

void CatchBullishDivergence(double& values[], int i)
{
   i++;
            ObjectDelete(divergenceUniqueID+"l"+DoubleToStr(Time[i],0));
            ObjectDelete(divergenceUniqueID+"l"+"os" + DoubleToStr(Time[i],0));            
   if (!IsIndicatorLow(values,i)) return;  

   //
   //
   //
   //
   //

   int currentLow = i;
   int lastLow    = GetIndicatorLastLow(values,i+1);
      if (values[currentLow] > values[lastLow] && Low[currentLow] < Low[lastLow])
      {
         if(divergenceOnChartVisible)  DrawPriceTrendLine("l",Time[currentLow],Time[lastLow],Low[currentLow],Low[lastLow],divergenceBullishColor,STYLE_SOLID);
         if(divergenceOnValuesVisible) DrawIndicatorTrendLine("l",Time[currentLow],Time[lastLow],values[currentLow],values[lastLow],divergenceBullishColor,STYLE_SOLID);
      }
      if (values[currentLow] < values[lastLow] && Low[currentLow] > Low[lastLow])
      {
         if(divergenceOnChartVisible)  DrawPriceTrendLine("l",Time[currentLow],Time[lastLow],Low[currentLow],Low[lastLow], divergenceBullishColor, STYLE_DOT);
         if(divergenceOnValuesVisible) DrawIndicatorTrendLine("l",Time[currentLow],Time[lastLow],values[currentLow],values[lastLow], divergenceBullishColor, STYLE_DOT);
      }
}

//
//
//
//
//

void CatchBearishDivergence(double& values[], int i)
{
   i++; 
            ObjectDelete(divergenceUniqueID+"h"+DoubleToStr(Time[i],0));
            ObjectDelete(divergenceUniqueID+"h"+"os" + DoubleToStr(Time[i],0));            
   if (IsIndicatorPeak(values,i) == false) return;

   //
   //
   //
   //
   //
      
   int currentPeak = i;
   int lastPeak = GetIndicatorLastPeak(values,i+1);
      if (values[currentPeak] < values[lastPeak] && High[currentPeak]>High[lastPeak])
      {
         if (divergenceOnChartVisible)  DrawPriceTrendLine("h",Time[currentPeak],Time[lastPeak],High[currentPeak],High[lastPeak],divergenceBearishColor,STYLE_DOT);
         if (divergenceOnValuesVisible) DrawIndicatorTrendLine("h",Time[currentPeak],Time[lastPeak],values[currentPeak],values[lastPeak],divergenceBearishColor,STYLE_DOT);
      }
      if(values[currentPeak] > values[lastPeak] && High[currentPeak] < High[lastPeak])
      {
         if (divergenceOnChartVisible)  DrawPriceTrendLine("h",Time[currentPeak],Time[lastPeak],High[currentPeak],High[lastPeak], divergenceBearishColor, STYLE_DOT);
         if (divergenceOnValuesVisible) DrawIndicatorTrendLine("h",Time[currentPeak],Time[lastPeak],values[currentPeak],values[lastPeak], divergenceBearishColor, STYLE_DOT);
      }
}

//
//
//
//
//

bool IsIndicatorPeak(double& values[], int i) { return(values[i] >= values[i+1] && values[i] > values[i+2] && values[i] > values[i-1]); }
bool IsIndicatorLow( double& values[], int i) { return(values[i] <= values[i+1] && values[i] < values[i+2] && values[i] < values[i-1]); }

int GetIndicatorLastPeak(double& values[], int shift)
{
   for(int i = shift+5; i<Bars; i++)
         if (values[i] >= values[i+1] && values[i] > values[i+2] && values[i] >= values[i-1] && values[i] > values[i-2]) return(i);
   return(-1);
}
int GetIndicatorLastLow(double& values[], int shift)
{
   for(int i = shift+5; i<Bars; i++)
         if (values[i] <= values[i+1] && values[i] < values[i+2] && values[i] <= values[i-1] && values[i] < values[i-2]) return(i);
   return(-1);
}

//+----------------------------------------------------------------------------------------------------------------------------------+
//|                                                                  
//+----------------------------------------------------------------------------------------------------------------------------------+
//
//
//
//
//

void DrawPriceTrendLine(string first,datetime t1, datetime t2, double p1, double p2, color lineColor, double style)
{
   string   label = divergenceUniqueID+first+"os"+DoubleToStr(t1,0);
   if (Interpolate) t2 += Period()*60-1;
    
   ObjectDelete(label);
      ObjectCreate(label, OBJ_TREND, 0, t1+Period()*60-1, p1, t2, p2, 0, 0);
         ObjectSet(label, OBJPROP_RAY, false);
         ObjectSet(label, OBJPROP_COLOR, lineColor);
         ObjectSet(label, OBJPROP_STYLE, style);
}
void DrawIndicatorTrendLine(string first,datetime t1, datetime t2, double p1, double p2, color lineColor, double style)
{
   int indicatorWindow = WindowFind(shortName);
   if (indicatorWindow < 0) return;
   if (Interpolate) t2 += Period()*60-1;
   
   string label = divergenceUniqueID+first+DoubleToStr(t1,0);
   ObjectDelete(label);
      ObjectCreate(label, OBJ_TREND, indicatorWindow, t1+Period()*60-1, p1, t2, p2, 0, 0);
         ObjectSet(label, OBJPROP_RAY, false);
         ObjectSet(label, OBJPROP_COLOR, lineColor);
         ObjectSet(label, OBJPROP_STYLE, style);
}

//+--------------------------------------------------------------------------------------+
//|                                                                                      |
//+--------------------------------------------------------------------------------------+
//
//
//
//
//

void manageLine(int i)
{
   if (ShowLines)
   {
      string lookFor = LinesIdentifier+":"+Time[i]; ObjectDelete(lookFor);
      if (trend[i]!=trend[i+1])
      {
         if (ShowLinesUp   && trend[i] == 1) drawLine(i,LinesUpColor);
         if (ShowLinesDown && trend[i] ==-1) drawLine(i,LinesDnColor);
      }
   }
}               

//
//
//
//
//

void drawLine(int i,color theColor)
{
   string name = LinesIdentifier+":"+Time[i];
      ObjectCreate(name,OBJ_VLINE,0,Time[i],0);
         ObjectSet(name,OBJPROP_COLOR,theColor);
         ObjectSet(name,OBJPROP_WIDTH,0);
         ObjectSet(name,OBJPROP_STYLE,STYLE_DOT);
        }

//
//
//
//
//

void deleteLines()
{
   string lookFor       = LinesIdentifier+":";
   int    lookForLength = StringLen(lookFor);
   for (int i=ObjectsTotal()-1; i>=0; i--)
   {
      string objectName = ObjectName(i);
         if (StringSubstr(objectName,0,lookForLength) == lookFor) ObjectDelete(objectName);
   }
}


//+------------------------------------------------------------------------------------------+
//|                                                                                          |
//+------------------------------------------------------------------------------------------+
//
//
//
//
//

void manageAlerts()
{
   if (!calculateValue && alertsOn)
   {
      if (alertsOnCurrent)
           int whichBar = 0;
      else     whichBar = 1; whichBar = iBarShift(NULL,0,iTime(NULL,timeFrame,whichBar));
      if (trend[whichBar] != trend[whichBar+1])
      {
         if (trend[whichBar] == 1) doAlert(whichBar,"up");
         if (trend[whichBar] ==-1) doAlert(whichBar,"down");
      }         
   }
}   

//
//
//
//
//

void doAlert(int forBar, string doWhat)
{
   static string   previousAlert="nothing";
   static datetime previousTime;
   string message;
   
      if (previousAlert != doWhat || previousTime != Time[forBar]) {
          previousAlert  = doWhat;
          previousTime   = Time[forBar];

          //
          //
          //
          //
          //

          message =  StringConcatenate(Symbol()," at ",TimeToStr(TimeLocal(),TIME_SECONDS)," dtosc trend changed to ",doWhat);
             if (alertsMessage) Alert(message);
             if (alertsEmail)   SendMail(StringConcatenate(Symbol(),"dtosc "),message);
             if (alertsSound)   PlaySound("enter now.wav");//PlaySound("alert2.wav");********************** Changed
      }
}


//+--------------------------------------------------------------------------------------------------------------------------+
//|                                                                                                                          |
//+--------------------------------------------------------------------------------------------------------------------------+
//
//
//
//
//

double wrk[][20];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iDSmooth(double price, double length, double phase, int i, int s=0)
{
   if (SmoothDouble)
         return (iSmooth(iSmooth(price,MathSqrt(length),phase,i,s),MathSqrt(length),phase,i,s+10));
   else  return (iSmooth(price,length,phase,i,s));
}

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (length <=1) return(price);
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[r][k+s]=price; for(; k<10; k++) wrk[r][k+s]=0; return(price); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}


//+---------------------------------------------------------------------------------------------------------+
//|                                                                                                         |
//+---------------------------------------------------------------------------------------------------------+
//
//
//
//
//

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = StringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string StringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int tchar = StringGetChar(s, length);
         if((tchar > 96 && tchar < 123) || (tchar > 223 && tchar < 256))
                     s = StringSetChar(s, length, tchar - 32);
         else if(tchar > -33 && tchar < 0)
                     s = StringSetChar(s, length, tchar + 224);
   }
   return(s);
}
//==================================================================+