//+------------------------------------------------------------------+
//|                       Gann High-Low Activator _ MTF _ Alerts.mq4 |
//|                                                                  |
//|                                                                  |
//+------------------------------------------------------------------+


#property indicator_chart_window
#property indicator_buffers 5
#property indicator_color1  Green
#property indicator_color2  Red
#property indicator_color3  Orange
#property indicator_width1  2
#property indicator_width2  2
#property indicator_width3  2



extern string TimeFrame       = "Current time frame";
extern int    Lb              = 10;
extern bool   alertsOn        = false;
extern bool   alertsOnCurrent = true;
extern bool   alertsMessage   = true;
extern bool   alertsSound     = false;
extern bool   alertsEmail     = false;
input bool    ArrowOnFirst    = true;                 // Arrow on first mtf bar
input int     ArrowCodeUp     = 233;                  // Arrow code up
input int     ArrowCodeDn     = 234;                  // Arrow code down
input double  ArrowGapUp      = 0.5;                  // Gap for arrow up        
input double  ArrowGapDn      = 0.5;                  // Gap for arrow down
input color   ArrowUpColor    = clrGreen;    // Up arrow color
input color   ArrowDnColor    = clrRed;          // Down arrow color                    
input int     ArrowUpSize     = 0;                    // Up arrow size
input int     ArrowDnSize     = 0;                    // Down arrow size



double gup[];
double gdna[];
double gdnb[];
double trend[];
double arrowu[];
double arrowd[];



int    timeFrame;
string indicatorFileName;
bool   returnBars;
bool   calculateValue;



int init()
{
   IndicatorBuffers(6);
   SetIndexBuffer(0,gup);     SetIndexStyle(0,DRAW_LINE); SetIndexDrawBegin(0,Lb+1);
   SetIndexBuffer(1,gdna);    SetIndexStyle(1,DRAW_LINE); SetIndexDrawBegin(1,Lb+1);
   SetIndexBuffer(2,gdnb);    SetIndexStyle(2,DRAW_LINE); SetIndexDrawBegin(2,Lb+1);
   SetIndexBuffer(3,arrowu);  SetIndexStyle(3,DRAW_ARROW,EMPTY,ArrowUpSize,ArrowUpColor); SetIndexArrow(3,ArrowCodeUp);
   SetIndexBuffer(4,arrowd);  SetIndexStyle(4,DRAW_ARROW,EMPTY,ArrowDnSize,ArrowDnColor); SetIndexArrow(4,ArrowCodeDn);
   SetIndexBuffer(5,trend);
   

      
         indicatorFileName = WindowExpertName();
         calculateValue    = (TimeFrame=="calculateValue"); if (calculateValue) return(0);
         returnBars        = (TimeFrame=="returnBars");     if (returnBars)     return(0);
         timeFrame         = stringToTimeFrame(TimeFrame);
      

      
   IndicatorShortName(timeFrameToString(timeFrame)+" Gann high/low activator ("+Lb+")");
         
   return(0);
}



int start()
{
   int counted_bars=IndicatorCounted();
   int i,limit;

   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
           limit=MathMin(Bars-counted_bars,Bars-1);
           if (returnBars) { gup[0] = limit+1; return(0); }



   if (calculateValue || timeFrame == Period())
   {
      if (!calculateValue && trend[limit]==-1) CleanPoint(limit,gdna,gdnb);
      for(i=limit;i>=0;i--)
      {
         gdna[i]  = EMPTY_VALUE;
         gdnb[i]  = EMPTY_VALUE;
         arrowu[i] = EMPTY_VALUE;
         arrowd[i] = EMPTY_VALUE;
         trend[i] = trend[i+1];
            if(Close[i]>iMA(Symbol(),0,Lb,0,MODE_SMA,PRICE_HIGH,i+1)) trend[i] =  1;
            if(Close[i]<iMA(Symbol(),0,Lb,0,MODE_SMA,PRICE_LOW,i+1))  trend[i] = -1;
      
            if(trend[i] == -1)
                  gup[i] = iMA(Symbol(),0,Lb,0,MODE_SMA,PRICE_HIGH,i+1);
            else  gup[i] = iMA(Symbol(),0,Lb,0,MODE_SMA,PRICE_LOW,i+1);
            if (!calculateValue && trend[i]==-1) PlotPoint(i,gdna,gdnb,gup);
            if (trend[i]!= trend[i+1])
            {
               if (trend[i] ==  1) arrowu[i] = fmin(gup[i],Low[i]) -iATR(NULL,0,15,i)*ArrowGapUp;
               if (trend[i] == -1) arrowd[i] = fmax(gup[i],High[i])+iATR(NULL,0,15,i)*ArrowGapDn;
            }
      }
      manageAlerts();
      return(0);
   }      


   int shift = -1; if (ArrowOnFirst) shift=1;
   limit = MathMax(limit,MathMin(Bars-1,iCustom(NULL,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));
   if (trend[limit]==-1) CleanPoint(limit,gdna,gdnb);
   for(i=limit; i>=0; i--)
   {
      int y = iBarShift(NULL,timeFrame,Time[i]);   
      int z = iBarShift(NULL,timeFrame,Time[i+shift]);   
         gup[i]   = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Lb,alertsOn,alertsOnCurrent,alertsMessage,alertsSound,alertsEmail,ArrowOnFirst,ArrowCodeUp,ArrowCodeDn,ArrowGapUp,ArrowGapDn,ArrowUpColor,ArrowDnColor,ArrowUpSize,ArrowDnSize,0,y);
         trend[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Lb,alertsOn,alertsOnCurrent,alertsMessage,alertsSound,alertsEmail,ArrowOnFirst,ArrowCodeUp,ArrowCodeDn,ArrowGapUp,ArrowGapDn,ArrowUpColor,ArrowDnColor,ArrowUpSize,ArrowDnSize,5,y);
         gdna[i]  = EMPTY_VALUE;
         gdnb[i]  = EMPTY_VALUE;
         arrowu[i] = EMPTY_VALUE;
         arrowd[i] = EMPTY_VALUE;
      if (y!=z)
      {
         arrowu[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Lb,alertsOn,alertsOnCurrent,alertsMessage,alertsSound,alertsEmail,ArrowOnFirst,ArrowCodeUp,ArrowCodeDn,ArrowGapUp,ArrowGapDn,ArrowUpColor,ArrowDnColor,ArrowUpSize,ArrowDnSize,3,y);
         arrowd[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateValue",Lb,alertsOn,alertsOnCurrent,alertsMessage,alertsSound,alertsEmail,ArrowOnFirst,ArrowCodeUp,ArrowCodeDn,ArrowGapUp,ArrowGapDn,ArrowUpColor,ArrowDnColor,ArrowUpSize,ArrowDnSize,4,y);
      }         
         if (trend[i]==-1) PlotPoint(i,gdna,gdnb,gup);
   }
   return(0);
}



void manageAlerts()
{
   if (alertsOn)
   {
      if (alertsOnCurrent)
           int whichBar = 0;
      else     whichBar = 1; 
      if (trend[whichBar] != trend[whichBar+1])
      {
         if (trend[whichBar] == 1) doAlert(whichBar,"up");
         if (trend[whichBar] ==-1) doAlert(whichBar,"down");
      }         
   }
}   



void doAlert(int forBar, string doWhat)
{
   static string   previousAlert="nothing";
   static datetime previousTime;
   string message;
   
      if (previousAlert != doWhat || previousTime != Time[forBar]) {
          previousAlert  = doWhat;
          previousTime   = Time[forBar];



          message =  timeFrameToString(Period())+" "+Symbol()+" at "+TimeToStr(TimeLocal(),TIME_SECONDS)+" Gann HL activator trend changed to "+doWhat;
             if (alertsMessage) Alert(message);
             if (alertsEmail)   SendMail(StringConcatenate(Symbol(),"Gann HL "),message);
             if (alertsSound)   PlaySound("alert2.wav");
      }
}



string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};



int stringToTimeFrame(string tfs)
{
   tfs = stringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}



string stringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int tchar = StringGetChar(s, length);
         if((tchar > 96 && tchar < 123) || (tchar > 223 && tchar < 256))
                     s = StringSetChar(s, length, tchar - 32);
         else if(tchar > -33 && tchar < 0)
                     s = StringSetChar(s, length, tchar + 224);
   }
   return(s);
}



void CleanPoint(int i,double& first[],double& second[])
{
   if ((second[i]  != EMPTY_VALUE) && (second[i+1] != EMPTY_VALUE))
        second[i+1] = EMPTY_VALUE;
   else
      if ((first[i] != EMPTY_VALUE) && (first[i+1] != EMPTY_VALUE) && (first[i+2] == EMPTY_VALUE))
          first[i+1] = EMPTY_VALUE;
}


void PlotPoint(int i,double& first[],double& second[],double& from[])
{
   if (first[i+1] == EMPTY_VALUE)
      {
         if (first[i+2] == EMPTY_VALUE) {
                first[i]   = from[i];
                first[i+1] = from[i+1];
                second[i]  = EMPTY_VALUE;
            }
         else {
                second[i]   =  from[i];
                second[i+1] =  from[i+1];
                first[i]    = EMPTY_VALUE;
            }
      }
   else
      {
         first[i]  = from[i];
         second[i] = EMPTY_VALUE;
      }
}