//+------------------------------------------------------------------+
//|                                         Volume-weigthed MACD.mq4 |
//|                      Copyright © 2004, MetaQuotes Software Corp. |
//|                                       http://www.metaquotes.net/ |
//|                                       Modified by sangmane       |
//+------------------------------------------------------------------+
#property  copyright "Copyright © 2004, MetaQuotes Software Corp."
#property  link      "http://www.metaquotes.net/"
//---- indicator settings
#property  indicator_separate_window
#property  indicator_buffers 3
#property  indicator_color1  Orange
#property  indicator_color2  Red
#property  indicator_color3  Silver
#property  indicator_style2  STYLE_DOT

//---- indicator parameters
extern int FastEMA=12;
extern int SlowEMA=26;
extern int SignalSMA=9;
//---- indicator buffers
double     MacdBuffer[];
double     SignalBuffer[];
double     OsmaBuffer[];
double     VolBuffer[];
double     VolPriceBuffer[];

//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
//---- drawing settings
   IndicatorBuffers(5);
   SetIndexStyle(0,DRAW_LINE);
   SetIndexStyle(1,DRAW_LINE);
   SetIndexStyle(2,DRAW_HISTOGRAM);
   SetIndexDrawBegin(1,SignalSMA);
   IndicatorDigits(Digits+1);
//---- indicator buffers mapping
   SetIndexBuffer(0,MacdBuffer);
   SetIndexBuffer(1,SignalBuffer);
   SetIndexBuffer(2,OsmaBuffer);
   SetIndexBuffer(3,VolBuffer);
   SetIndexBuffer(4,VolPriceBuffer);
//---- name for DataWindow and indicator subwindow label
   IndicatorShortName("MACD Volume-weighted("+FastEMA+","+SlowEMA+","+SignalSMA+")");
   SetIndexLabel(0,"MACD Volume-weighted");
   SetIndexLabel(1,"Signal");
//---- initialization done
   return(0);
  }
//+------------------------------------------------------------------+
//| Moving Averages Convergence/Divergence                           |
//+------------------------------------------------------------------+
int start()
  {
   int limit;
   int counted_bars=IndicatorCounted();
//---- last counted bar will be recounted
   if(counted_bars>0) counted_bars--;
   limit=Bars-counted_bars;
//---- macd counted in the 1-st buffer
   for(int i=0; i<limit; i++)
     {
      VolBuffer[i] = Volume[i];
      VolPriceBuffer[i] = Volume[i]*Close[i];
     }
   for(i=0; i<limit; i++)      
     {
      double EmaVolFast = iMAOnArray(VolBuffer,0,FastEMA,0,MODE_EMA,i);
      double EmaVolSlow = iMAOnArray(VolBuffer,0,SlowEMA,0,MODE_EMA,i);
      if(EmaVolFast!=0 && EmaVolSlow!=0)
        MacdBuffer[i] = iMAOnArray(VolPriceBuffer,0,FastEMA,0,MODE_EMA,i)/EmaVolFast - 
                        iMAOnArray(VolPriceBuffer,0,SlowEMA,0,MODE_EMA,i)/EmaVolSlow;
     }
//---- signal line counted in the 2-nd buffer
   for(i=0; i<limit; i++)
     {
      SignalBuffer[i]=iMAOnArray(MacdBuffer,Bars,SignalSMA,0,MODE_EMA,i);
      OsmaBuffer[i] = MacdBuffer[i] - SignalBuffer[i];
     }
//---- done
   return(0);
  }
//+------------------------------------------------------------------+