//http://codebase.mql4.com/ru/4333
//post fxcanada (12.09.2008 12:01) 
//----
#property indicator_chart_window
#property indicator_buffers 5
#property indicator_color1 DodgerBlue
#property indicator_color2 DodgerBlue
#property indicator_color3 Magenta
#property indicator_color4 Magenta
#property indicator_color5 Gold


extern int TimeFrame = 0;
extern string note1 = "Degree - power of Polynomial :";
extern string note2 = "0- linear; 1- parabolic; 2- Third-power";
extern int degree = 2;
extern double istd = 1.0;
extern double wstd = 1.618;
extern int bars = 100;
extern int shift = 0;

//-----
double fx[],sqh[],sql[],sqhh[],sqll[];

double ai[10,10],b[10],x[10],sx[20];
double sum; 
int ip,p,n,f;
double qq,mm,tt;
int ii,jj,kk,ll,nn;
double sqM,sqV,sq;
int bar;
int i0 = 0;


//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init()
{
  SetIndexBuffer(0, sqh);
  SetIndexBuffer(1, sql);
  SetIndexBuffer(2, sqhh);
  SetIndexBuffer(3, sqll);
  SetIndexBuffer(4, fx);
  

  SetIndexStyle(0, DRAW_LINE);
  SetIndexStyle(1, DRAW_LINE);
  SetIndexStyle(2, DRAW_LINE);
  SetIndexStyle(3, DRAW_LINE);
  SetIndexStyle(4, DRAW_LINE);
  
  
  SetIndexShift(0, shift);
  SetIndexShift(1, shift);
  SetIndexShift(2, shift);
  SetIndexShift(3, shift);
  SetIndexShift(4, shift);

  datetime time = iTime(NULL,TimeFrame,bars);
  bar = iBarShift(NULL,0,time);
Comment(time +"  "+bar);

  return(0);
}

//+------------------------------------------------------------------+
//| Custom indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit()
{
  ObjectDelete("regression channel");ObjectDelete("std channel");
  //clear();
  return(0);
}

//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start()
{
  if (Bars < bars) return(0);

//---- 
  if (degree>2) degree=2;  
  int mi; // переменная использующаяся только в start
  ip = bars;
  p=ip; // типа присваивание
  sx[1]=p+1; // примечание - [] - означает массив
  nn = degree+2;


   
//----------------------sx-------------------------------------------------------------------
  for(mi=1;mi<=nn*2-2;mi++) // математическое выражение - для всех mi от 1 до nn*2-2 
  {
    sum=0;
    for(n=i0;n<=i0+p;n++)
    {
       sum+=MathPow(n,mi);
    }
    sx[mi+1]=sum;
  }  
  //----------------------syx-----------
  for(mi=1;mi<=nn;mi++)
  {
    sum=0.00000;
    for(n=i0;n<=i0+p;n++)
    {
       if(mi==1) sum+=iClose(NULL,TimeFrame,n);
       else sum+=iClose(NULL,TimeFrame,n)*MathPow(n,mi-1);
    }
    b[mi]=sum;
  } 
//===============Matrix=======================================================================================================
  for(jj=1;jj<=nn;jj++)
  {
    for(ii=1; ii<=nn; ii++)
    {
       kk=ii+jj-1;
       ai[ii,jj]=sx[kk];
    }
  }  
//===============Gauss========================================================================================================
  for(kk=1; kk<=nn-1; kk++)
  {
    ll=0;
    mm=0;
    for(ii=kk; ii<=nn; ii++)
    {
       if(MathAbs(ai[ii,kk])>mm)
       {
          mm=MathAbs(ai[ii,kk]);
          ll=ii;
       }
    }
    if(ll==0) return(0);   
    if (ll!=kk)
    {
       for(jj=1; jj<=nn; jj++)
       {
          tt=ai[kk,jj];
          ai[kk,jj]=ai[ll,jj];
          ai[ll,jj]=tt;
       }
       tt=b[kk];
       b[kk]=b[ll];
       b[ll]=tt;
    }  
    for(ii=kk+1;ii<=nn;ii++)
    {
       qq=ai[ii,kk]/ai[kk,kk];
       for(jj=1;jj<=nn;jj++)
       {
          if(jj==kk) ai[ii,jj]=0;
          else ai[ii,jj]=ai[ii,jj]-qq*ai[kk,jj];
       }
       b[ii]=b[ii]-qq*b[kk];
    }
  }  
  x[nn]=b[nn]/ai[nn,nn];
  for(ii=nn-1;ii>=1;ii--)
  {
    tt=0;
    for(jj=1;jj<=nn-ii;jj++)
    {
       tt=tt+ai[ii,ii+jj]*x[ii+jj];
       x[ii]=(1/ai[ii,ii])*(b[ii]-tt);
    }
  } 
//===========================================================================================================================
  for(n=i0;n<=i0+p;n++)
  {
    sum=0;
    for(kk=1;kk<=degree+1;kk++)
    {
       sum+=x[kk+1]*MathPow(n,kk);
    }
    fx[n]=x[1]+sum;
  } 
//-----------------------------------Std-----------------------------------------------------------------------------------
  sqM=0.0;
   double e=0,a=0;

  for(n=i0;n<p;n++)
  {  
     e+=iClose(NULL,TimeFrame,n); 
  } 
   
  a=e/p;
  
  for(n=i0;n<p;n++)
  {  
    sqM+=MathPow(iClose(NULL,TimeFrame,n)-a,2);
  }
  
  sqV=MathSqrt(sqM/(p));

  for(n=i0;n<=p;n++)
  {
    sqh[n]=fx[n]+sqV*istd;
    sql[n]=fx[n]-sqV*istd;
    sqhh[n]=fx[n]+sqV*wstd;
    sqll[n]=fx[n]-sqV*wstd;
    
  }
  return(0);
}
//+------------------------------------------------------------------+